CMakeLists.txt

cmake_minimum_required(VERSION 3.10)

if(WIN32)
    # In Qt 5.1+ we have our own main() function, don't autolink to qtmain on Windows
    cmake_policy(SET CMP0020 OLD)
endif()

project(Launcher)
enable_testing()

string(COMPARE EQUAL "${CMAKE_SOURCE_DIR}" "${CMAKE_BUILD_DIR}" IS_IN_SOURCE_BUILD)
if(IS_IN_SOURCE_BUILD)
    message(FATAL_ERROR "You are building the Launcher in-source. Please separate the build tree from the source tree.")
endif()

if (CMAKE_SYSTEM_NAME STREQUAL "Linux")
    if(CMAKE_HOST_SYSTEM_VERSION MATCHES ".*[Mm]icrosoft.*" OR
        CMAKE_HOST_SYSTEM_VERSION MATCHES ".*WSL.*"
    )
        message(FATAL_ERROR "Building the Launcher is not supported in Linux-on-Windows distributions.")
    endif()
endif()

option(Launcher_RUN_CLANG_TIDY "Run clang-tidy with the compiler." OFF)
if(Launcher_RUN_CLANG_TIDY)
  find_program(CLANG_TIDY_COMMAND NAMES clang-tidy)
  if(NOT CLANG_TIDY_COMMAND)
    message(WARNING "CMake_RUN_CLANG_TIDY is ON but clang-tidy is not found!")
    set(DO_CLANG_TIDY "" CACHE STRING "" FORCE)
  else()
    set(CLANG_TIDY_CHECKS "-modernize-use-trailing-return-type,-readability-magic-numbers,-modernize-avoid-c-arrays")
    set(DO_CLANG_TIDY "${CLANG_TIDY_COMMAND};-checks=${CLANG_TIDY_CHECKS};-header-filter='${CMAKE_SOURCE_DIR}/src/*'")
  endif()
  # TODO: make this per-target, differentiate between libraries and main codebase
  set(CMAKE_CXX_CLANG_TIDY ${DO_CLANG_TIDY})
endif()


##################################### Set CMake options #####################################
set(CMAKE_AUTOMOC ON)
set(CMAKE_INCLUDE_CURRENT_DIR ON)

set(CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/cmake/")

# Output all executables and shared libs in the main build folder, not in subfolders.
set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR})
if(UNIX)
    set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR})
endif()
set(CMAKE_JAVA_TARGET_OUTPUT_DIR ${PROJECT_BINARY_DIR}/jars)

######## Set compiler flags ########
set(CMAKE_CXX_STANDARD_REQUIRED true)
set(CMAKE_C_STANDARD_REQUIRED true)
set(CMAKE_CXX_STANDARD 11)
set(CMAKE_C_STANDARD 11)
include(GenerateExportHeader)
set(CMAKE_CXX_FLAGS " -Wall -pedantic -Wno-deprecated-declarations -D_GLIBCXX_USE_CXX11_ABI=0 -fstack-protector-strong --param=ssp-buffer-size=4 ${CMAKE_CXX_FLAGS}")
set(CMAKE_CXX_FLAGS_RELEASE " -O3 -D_FORTIFY_SOURCE=2 ${CMAKE_CXX_FLAGS_RELEASE}")
if(UNIX AND APPLE)
    set(CMAKE_CXX_FLAGS " -stdlib=libc++ ${CMAKE_CXX_FLAGS}")
endif()
set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} -Werror -Werror=return-type -O0")

# Fix build with Qt 5.13
set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -DQT_NO_DEPRECATED_WARNINGS=Y")

##################################### Set Application options #####################################

######## Set URLs ########
set(Launcher_NEWS_URL "https://multimc.org/posts.html" CACHE STRING "URL to open Launcher's news.")
set(Launcher_NEWS_RSS_URL "https://multimc.org/rss.xml" CACHE STRING "URL to fetch Launcher's news RSS feed from.")

######## Set version numbers ########
# The version is 5.<minor>.<build> (the Design repo's Updater.md, Versions): the minor version
# goes up here, by hand, when work on a bigger user-facing change starts, so the builds working
# towards it carry it, and Stable gets it when one of them is promoted. The major version
# changes only for a break (the data layout move, say). The build number comes from the release
# pipeline and only goes up. Tagging a build (Testing, Stable) never changes its version.
set(Launcher_VERSION_MAJOR    5)
set(Launcher_VERSION_MINOR    0)

# Build number
set(Launcher_VERSION_BUILD -1 CACHE STRING "Build number. -1 for no build number.")
# Windows version resources hold each part in 16 bits
if(Launcher_VERSION_BUILD GREATER 65535)
    message(FATAL_ERROR "Build number ${Launcher_VERSION_BUILD} doesn't fit a Windows version resource (at most 65535)")
endif()
if(Launcher_VERSION_BUILD LESS 0)
    set(Launcher_VERSION_BUILD_PART 0)
else()
    set(Launcher_VERSION_BUILD_PART ${Launcher_VERSION_BUILD})
endif()
set(Launcher_VERSION_NAME "${Launcher_VERSION_MAJOR}.${Launcher_VERSION_MINOR}.${Launcher_VERSION_BUILD_PART}")

# Build platform.
set(Launcher_BUILD_PLATFORM "" CACHE STRING "A short string identifying the platform that this build was built for. Only used by the notification system and to display in the about dialog.")

# Our sites, each a list of base URLs: the main server first, then its copies, in the order they are tried.
# Every URL on a site is one of its base URLs and a path.
set(Launcher_FILES_MIRRORS "https://files.multimc.org/;https://files-r2.multimc.org/" CACHE STRING "Base URLs of the files site (updates, notifications, translations, ...), in order.")
set(Launcher_META_MIRRORS "https://meta.multimc.org/;https://meta-r2.multimc.org/" CACHE STRING "Base URLs of the meta site, in order.")
foreach(site FILES META)
    if(NOT Launcher_${site}_MIRRORS)
        message(FATAL_ERROR "Launcher_${site}_MIRRORS must have at least one base URL")
    endif()
    foreach(url ${Launcher_${site}_MIRRORS})
        if(NOT url MATCHES "^https?://[^/]+/$")
            message(FATAL_ERROR "Launcher_${site}_MIRRORS: ${url} is not a base URL like https://example.org/")
        endif()
    endforeach()
    # as C++ string literals, one per URL: "a", "b"
    string(REPLACE ";" "\", \"" Launcher_${site}_MIRRORS_LITERALS "\"${Launcher_${site}_MIRRORS}\"")
endforeach()

# Which updater a build uses: 1, the current one, or 2, the new one (Design/Updater.md in the
# MultiMC repository). Both are built into every build.
set(Launcher_UPDATER_VERSION "1" CACHE STRING "The updater this build uses: 1 or 2")
# Updater v2: pinned root keys: Ed25519 public keys, 64 hex digits each
set(Launcher_UPDATER_ROOT_KEYS "" CACHE STRING "Updater v2: pinned root public keys, a list")
# Updater v2: the keys document compiled in as the floor; it must list exactly the pinned root keys
set(Launcher_UPDATER_KEYS_FLOOR "" CACHE FILEPATH "Updater v2: the keys document compiled in")
set(Launcher_UPDATER_SERIAL_FLOOR "0" CACHE STRING "Updater v2: the lowest tags serial accepted")
# Updater v2: the variant ID this build is, e.g. linux-x86_64-qt5 (see Design/UpdaterFormats.md)
set(Launcher_UPDATER_VARIANT "" CACHE STRING "Updater v2: this build's variant ID")
if(NOT Launcher_UPDATER_VERSION MATCHES "^[12]$")
    message(FATAL_ERROR "Launcher_UPDATER_VERSION must be 1 or 2, not '${Launcher_UPDATER_VERSION}'")
endif()
if(NOT Launcher_UPDATER_SERIAL_FLOOR MATCHES "^(0|[1-9][0-9]*)$")
    message(FATAL_ERROR "Launcher_UPDATER_SERIAL_FLOOR must be a number, not '${Launcher_UPDATER_SERIAL_FLOOR}'")
endif()
foreach(key ${Launcher_UPDATER_ROOT_KEYS})
    if(NOT key MATCHES "^[0-9a-f]+$")
        message(FATAL_ERROR "Launcher_UPDATER_ROOT_KEYS: ${key} is not lowercase hex")
    endif()
endforeach()
# as C++ string literals, one per key: "a", "b"
if(Launcher_UPDATER_ROOT_KEYS)
    string(REPLACE ";" "\", \"" Launcher_UPDATER_ROOT_KEYS_LITERALS "\"${Launcher_UPDATER_ROOT_KEYS}\"")
endif()
# The keys document as a string literal of its exact bytes
set(Launcher_UPDATER_KEYS_FLOOR_BYTES "")
if(Launcher_UPDATER_KEYS_FLOOR)
    if(NOT EXISTS "${Launcher_UPDATER_KEYS_FLOOR}")
        message(FATAL_ERROR "Launcher_UPDATER_KEYS_FLOOR: ${Launcher_UPDATER_KEYS_FLOOR} doesn't exist")
    endif()
    set_property(DIRECTORY APPEND PROPERTY CMAKE_CONFIGURE_DEPENDS "${Launcher_UPDATER_KEYS_FLOOR}")
    file(READ "${Launcher_UPDATER_KEYS_FLOOR}" floor_hex HEX)
    string(REGEX REPLACE "([0-9a-f][0-9a-f])" "\\\\x\\1" Launcher_UPDATER_KEYS_FLOOR_BYTES "${floor_hex}")
endif()

#### Check the current Git commit and branch
include(GetGitRevisionDescription)
get_git_head_revision(Launcher_GIT_REFSPEC Launcher_GIT_COMMIT)

message(STATUS "Git commit: ${Launcher_GIT_COMMIT}")
message(STATUS "Git refspec: ${Launcher_GIT_REFSPEC}")

set(Launcher_RELEASE_VERSION_NAME "${Launcher_VERSION_NAME}")

#### Custom target to just print the version.
add_custom_target(version echo "Version: ${Launcher_RELEASE_VERSION_NAME}")
add_custom_target(tcversion echo "\\#\\#teamcity[setParameter name=\\'env.LAUNCHER_VERSION\\' value=\\'${Launcher_RELEASE_VERSION_NAME}\\']")

################################ 3rd Party Libs ################################

# Find the required Qt parts
find_package(Qt5Core REQUIRED)
find_package(Qt5Widgets REQUIRED)
find_package(Qt5Concurrent REQUIRED)
find_package(Qt5Network REQUIRED)
find_package(Qt5Test REQUIRED)
find_package(Qt5Xml REQUIRED)

# The Qt5 cmake files don't provide its install paths, so ask qmake.
include(QMakeQuery)
query_qmake(QUERY QT_INSTALL_PLUGINS RESULT QT_PLUGINS_DIR)
query_qmake(QUERY QT_INSTALL_LIBS RESULT QT_LIBS_DIR)
query_qmake(QUERY QT_INSTALL_LIBEXECS RESULT QT_LIBEXECS_DIR)

if (Qt5_POSITION_INDEPENDENT_CODE)
    SET(CMAKE_POSITION_INDEPENDENT_CODE ON)
endif()

####################################### Branding #######################################

set(Launcher_CommonName "MultiMC")

set(Launcher_Copyright "MultiMC Contributors")
set(Launcher_Domain "multimc.org")
set(Launcher_Name "${Launcher_CommonName}")
# the 5 is in the version now (5.<minor>.<build>), not in the name
set(Launcher_DisplayName "${Launcher_CommonName}")
set(Launcher_UserAgent "${Launcher_CommonName}/5.0")
set(Launcher_ConfigFile "multimc.cfg")
set(Launcher_Git "https://github.com/MultiMC/Launcher")

set(Launcher_Branding_ICNS "${PROJECT_SOURCE_DIR}/branding/${Launcher_CommonName}.icns")
# with the version filled in (major,minor,build,0: the Microsoft Store keeps the fourth part)
set(Launcher_Branding_SourceDir "${PROJECT_SOURCE_DIR}/branding")
configure_file("${PROJECT_SOURCE_DIR}/branding/multimc.rc.in" "${PROJECT_BINARY_DIR}/branding/multimc.rc" @ONLY)
set(Launcher_Branding_WindowsRC "${PROJECT_BINARY_DIR}/branding/multimc.rc")
set(Launcher_Branding_LogoQRC "${PROJECT_SOURCE_DIR}/branding/logo.qrc")

set(Launcher_PASTE_EE_API_KEY "utLvciUouSURFzfjPxLBf5W4ISsUX4pwBDF7N1AfZ")
set(Launcher_MSA_CLIENT_ID "499546d9-bbfe-4b9b-a086-eb3d75afb78f")
set(Launcher_IMGUR_CLIENT_ID "5b97b0713fba4a3")
set(Launcher_BUG_TRACKER_URL "https://github.com/MultiMC/Launcher/issues")
set(Launcher_DISCORD_URL "https://discord.gg/multimc")
set(Launcher_SUBREDDIT_URL "https://www.reddit.com/r/MultiMC/")
set(Launcher_PATREON_URL "https://www.patreon.com/multimc")

####################################### Install layout #######################################

# How to install the build results
set(Launcher_LAYOUT "auto" CACHE STRING "The layout for the launcher installation (auto, win-bundle, lin-nodeps, mac-bundle)")
set_property(CACHE Launcher_LAYOUT PROPERTY STRINGS auto win-bundle lin-nodeps mac-bundle)

if(Launcher_LAYOUT STREQUAL "auto")
    if(UNIX AND APPLE)
        set(Launcher_LAYOUT_REAL "mac-bundle")
    elseif(UNIX)
        set(Launcher_LAYOUT_REAL "lin-nodeps")
    elseif(WIN32)
        set(Launcher_LAYOUT_REAL "win-bundle")
    else()
        message(FATAL_ERROR "Cannot choose a sensible install layout for your platform.")
    endif()
else()
    set(Launcher_LAYOUT_REAL ${Launcher_LAYOUT})
endif()

if(Launcher_LAYOUT_REAL STREQUAL "mac-bundle")
    set(BINARY_DEST_DIR "${Launcher_Name}.app/Contents/MacOS")
    set(LIBRARY_DEST_DIR "${Launcher_Name}.app/Contents/MacOS")
    set(PLUGIN_DEST_DIR "${Launcher_Name}.app/Contents/MacOS")
    set(RESOURCES_DEST_DIR "${Launcher_Name}.app/Contents/Resources")
    set(JARS_DEST_DIR "${Launcher_Name}.app/Contents/MacOS/jars")

    set(BUNDLE_DEST_DIR ".")

    # Apps to bundle
    set(APPS "\${CMAKE_INSTALL_PREFIX}/${Launcher_Name}.app")

    # Mac bundle settings
    set(MACOSX_BUNDLE_BUNDLE_NAME "${Launcher_Name}")
    set(MACOSX_BUNDLE_INFO_STRING "${Launcher_Name}:  Minecraft launcher and management utility.")
    set(MACOSX_BUNDLE_GUI_IDENTIFIER "org.multimc.${Launcher_Name}")
    # three integers, as the App Store wants; the build part only goes up
    set(MACOSX_BUNDLE_BUNDLE_VERSION "${Launcher_VERSION_NAME}")
    set(MACOSX_BUNDLE_SHORT_VERSION_STRING "${Launcher_VERSION_NAME}")
    set(MACOSX_BUNDLE_LONG_VERSION_STRING "${Launcher_VERSION_NAME}")
    set(MACOSX_BUNDLE_ICON_FILE ${Launcher_Name}.icns)
    set(MACOSX_BUNDLE_COPYRIGHT "Copyright 2015-2024 ${Launcher_Copyright}")

    # directories to look for dependencies
    set(DIRS ${QT_LIBS_DIR} ${QT_LIBEXECS_DIR} ${CMAKE_LIBRARY_OUTPUT_DIRECTORY} ${CMAKE_RUNTIME_OUTPUT_DIRECTORY})

    # install as bundle
    set(INSTALL_BUNDLE "full")

    # Add the icon
    install(FILES ${Launcher_Branding_ICNS} DESTINATION ${RESOURCES_DEST_DIR} RENAME ${Launcher_Name}.icns)

elseif(Launcher_LAYOUT_REAL STREQUAL "lin-nodeps")
    set(BINARY_DEST_DIR "bin")
    set(LIBRARY_DEST_DIR "bin")
    set(PLUGIN_DEST_DIR "plugins")
    set(BUNDLE_DEST_DIR ".")
    set(RESOURCES_DEST_DIR ".")
    set(JARS_DEST_DIR "bin/jars")

    # install as bundle with no dependencies included
    set(INSTALL_BUNDLE "nodeps")

    # Set RPATH
    SET(Launcher_BINARY_RPATH "$ORIGIN/")

    # Install basic runner script
    configure_file(launcher/Launcher.in "${CMAKE_CURRENT_BINARY_DIR}/LauncherScript" @ONLY)
    install(PROGRAMS "${CMAKE_CURRENT_BINARY_DIR}/LauncherScript" DESTINATION ${BUNDLE_DEST_DIR} RENAME ${Launcher_Name})

elseif(Launcher_LAYOUT_REAL STREQUAL "win-bundle")
    set(BINARY_DEST_DIR ".")
    set(LIBRARY_DEST_DIR ".")
    set(PLUGIN_DEST_DIR ".")
    set(BUNDLE_DEST_DIR ".")
    set(RESOURCES_DEST_DIR ".")
    set(JARS_DEST_DIR "jars")

    # Apps to bundle
    set(APPS "\${CMAKE_INSTALL_PREFIX}/${Launcher_Name}.exe")

    # directories to look for dependencies
    set(DIRS ${QT_LIBS_DIR} ${QT_LIBEXECS_DIR} ${CMAKE_LIBRARY_OUTPUT_DIRECTORY} ${CMAKE_RUNTIME_OUTPUT_DIRECTORY})

    # install as bundle
    set(INSTALL_BUNDLE "full")
else()
    message(FATAL_ERROR "No sensible install layout set.")
endif()

################################ Included Libs ################################

include(ExternalProject)
set_directory_properties(PROPERTIES EP_BASE External)

option(NBT_BUILD_SHARED "Build NBT shared library" ON)
option(NBT_USE_ZLIB "Build NBT library with zlib support" OFF)
option(NBT_BUILD_TESTS "Build NBT library tests" OFF) #FIXME: fix unit tests.
set(NBT_NAME Launcher_nbt++)
set(NBT_DEST_DIR ${LIBRARY_DEST_DIR})
add_subdirectory(libraries/libnbtplusplus)

add_subdirectory(libraries/systeminfo) # system information library
add_subdirectory(libraries/hoedown) # markdown parser
add_subdirectory(libraries/launcher) # java based launcher part for Minecraft
add_subdirectory(libraries/javacheck) # java compatibility checker
add_subdirectory(libraries/xz-embedded) # xz compression
add_subdirectory(libraries/qrcode) # library for generating QR codes
add_subdirectory(libraries/quazip) # zip manipulation library
add_subdirectory(libraries/iconfix) # fork of Qt's QIcon loader
add_subdirectory(libraries/LocalPeer) # fork of a library from Qt solutions
add_subdirectory(libraries/classparser) # java class file parser
add_subdirectory(libraries/optional-bare)
add_subdirectory(libraries/tomlc99) # toml parser
add_subdirectory(libraries/monocypher) # signature checks for the updater
add_subdirectory(libraries/katabasis) # An OAuth2 library that tried to do too much

############################### Built Artifacts ###############################

add_subdirectory(buildconfig)

# NOTE: this must always be last to appease the CMake deity of quirky install command evaluation order.
add_subdirectory(launcher)