justfile

default:
    @just --list

install: install-java install-toolchains install-ndk install-ktlint

install-java:
    @echo "==> Install Temurin JDK 17"
    @brew install --cask temurin@17
    @./gradlew --version

install-toolchains:
    @echo Install toolchains for uniffi
    @cd ../core && just gemstone install-android-targets

install-ndk:
    @cd ../core && just gemstone install-ndk

install-ktlint:
    @echo "==> Install ktlint"
    @brew install ktlint

# Formats the Kotlin you changed; ktlint spends ~2s walking the whole tree.
format:
    #!/usr/bin/env bash
    set -euo pipefail
    files=$( { git diff --name-only --diff-filter=ACMR HEAD -- '*.kt'; git ls-files --others --exclude-standard -- '*.kt'; } | sed 's|^android/||' | sort -u )
    [ -z "$files" ] && exit 0
    echo "==> Running ktlint"
    echo "$files" | xargs ktlint --format --relative >/dev/null

format-all:
    @echo "==> Running ktlint on every file"
    @ktlint --format --relative "**/*.kt" "!**/build/**" >/dev/null

clean:
    #!/usr/bin/env bash
    set -euo pipefail
    find . ../core/gemstone/android -type d \( -name build -o -name .gradle -o -name .kotlin -o -name .cxx -o -name .externalNativeBuild \) -prune -exec rm -rf {} +
    echo "Android build folders cleaned"

build:
    @./gradlew assembleGoogleDebug

run: build
    @just _run-adb emulator

run-device: build
    @just _run-adb device

_run-adb TARGET:
    #!/usr/bin/env bash
    set -euo pipefail
    PACKAGE="com.gemwallet.android"
    if [ "{{TARGET}}" = "emulator" ]; then
        DEVICE=$(adb devices | awk '$2=="device" && $1 ~ /^emulator-/ {print $1; exit}')
        [ -z "$DEVICE" ] && { echo "No emulator found (try 'just start-emulator')"; exit 1; }
    else
        DEVICE=$(adb devices | awk '$2=="device" && $1 !~ /^emulator-/ {print $1; exit}')
        [ -z "$DEVICE" ] && { echo "No physical device found"; exit 1; }
    fi
    APK=$(find app/build/outputs/apk/google/debug -name '*.apk' | head -1)
    echo "==> Installing on $DEVICE..."
    adb -s "$DEVICE" install -r "$APK"
    echo "==> Launching app..."
    adb -s "$DEVICE" shell am start -W -n "$PACKAGE/$PACKAGE.MainActivity"
    echo "==> Streaming logs (Ctrl+C to stop)..."
    PID=""
    for _ in {1..60}; do
        PID=$(adb -s "$DEVICE" shell pidof -s "$PACKAGE" | tr -d '\r' || true)
        [ -n "$PID" ] && break
        sleep 0.5
    done
    if [ -z "$PID" ]; then
        echo "App process not found after launch; showing recent app errors"
        adb -s "$DEVICE" logcat -d -t 500 | grep -E "$PACKAGE|AndroidRuntime|FATAL EXCEPTION" || true
        exit 1
    fi
    trap 'echo; echo "==> Log streaming stopped."; exit 0' INT TERM
    set +e
    adb -s "$DEVICE" logcat --pid="$PID"
    STATUS=$?
    set -e
    case "$STATUS" in
        0|130|143)
            echo
            echo "==> Log streaming stopped."
            exit 0
            ;;
        *)
            exit "$STATUS"
            ;;
    esac

build-test:
    @./gradlew assembleGoogleDebugAndroidTest

test:
    @./gradlew --continue testGoogleDebugUnitTest testDebugUnitTest -PintegrationTests=skip

test-integration:
    @./gradlew --continue testGoogleDebugUnitTest testDebugUnitTest -PintegrationTests=only

test-all:
    @./gradlew --continue assembleGoogleDebug testGoogleDebugUnitTest testDebugUnitTest

lint:
    @./gradlew lint -x :gemstone:lintDebug

provision-emulator:
    @bash ./scripts/android_emulator.sh provision

start-emulator:
    @bash ./scripts/android_emulator.sh setup

stop-emulator:
    @bash ./scripts/android_emulator.sh shutdown

release:
    @BUILD_MODE=release ./gradlew clean :app:bundleGoogleRelease --no-configuration-cache

release-apk:
    @BUILD_MODE=release ./gradlew clean assembleUniversalRelease -PuseLegacyPackaging=true --no-configuration-cache

localize:
    @cd ../core && cargo run --package generate --bin generate localize android ../localization/app ../android/ui/src/main/res

generate: generate-models

generate-models:
    @echo "==> Generate models for Android"
    @cd ../core && cargo run --package generate --bin generate android ../android/gemcore/src/main/kotlin/com/wallet/core

generate-stone:
    @echo "==> Generate Gemstone bindings and native libraries for Android"
    @./gradlew :gemstone:bindgenKotlin :gemstone:buildCargoNdk --rerun-tasks

bump TARGET="patch":
    @cd .. && just bump {{TARGET}}