ESP32 using Arduino library + more compact code

[ngxson]

Hi, I'd like to share with you my implementation for ESP32 using Arduino library (can be deployed via platformio or Arduino IDE)

My version is more compact compared to the original one in the repo (using IDF library). However, it comes with the cost of removing many error handlers.

#include <Arduino.h>
#include "BLEDevice.h"
#include "BLEServer.h"
#include "BLEUtils.h"
#include "BLEBeacon.h"


/////////////////////////////////////////////////
// export by right click the accessory => copy adv key => byte array
uint8_t MY_PUBLIC_KEY[28] = {
  0x9d, 0xe1, 0xe0, 0x00,.......................
};
/////////////////////////////////////////////////


BLEAdvertising *pAdvertising;

static void esp_gap_cb(esp_gap_ble_cb_event_t event, esp_ble_gap_cb_param_t *param) {
  esp_err_t err;
  if (event == ESP_GAP_BLE_ADV_START_COMPLETE_EVT) {
    if ((err = param->adv_start_cmpl.status) != ESP_BT_STATUS_SUCCESS) {
      Serial.printf("Advertising start failed: %s\n", esp_err_to_name(err));
    } else {
      Serial.printf("Advertising started\n");
    }
  } else if (event == ESP_GAP_BLE_ADV_STOP_COMPLETE_EVT) {
    Serial.printf("Advertising stopped\n");
  }
}

static esp_bd_addr_t rnd_addr; // device MAC address
static uint8_t adv_hdr[7] = { // Advertisement fixed header
  0x1e, /* Length (30) */
  0xff, /* Manufacturer Specific Data (type 0xff) */
  0x4c, 0x00, /* Company ID (Apple) */
  0x12, 0x19, /* Offline Finding type and length */
  0x00 /* State (battery level) */
};

void setup() {
  Serial.begin(115200);
  BLEDevice::init("");
  pAdvertising = BLEDevice::getAdvertising();

  // prepare MAC
  memcpy(rnd_addr, MY_PUBLIC_KEY, 6);
  rnd_addr[0] = rnd_addr[0] | 0b11000000;
  Serial.print("MAC address ");
  for (size_t i = 0; i < 6; i++)
    Serial.printf(":%02x", rnd_addr[i]);
  Serial.println();

  // prepare adv payload
  // we use for loop to convert from byte array to std::string
  std::string adv_payload = "";
  for (size_t i = 0; i < sizeof(adv_hdr); i++)
    adv_payload += (char) adv_hdr[i]; // copy header
  for (size_t i = 6; i < sizeof(MY_PUBLIC_KEY); i++)
    adv_payload += (char) MY_PUBLIC_KEY[i]; // copy the rest of public key
  adv_payload += (char) (MY_PUBLIC_KEY[0] >> 6); // append two bits of public key
  adv_payload += (char) 0x00; // append hint byte
  Serial.printf("Payload size: %d\n", adv_payload.size());

  // setup BLEAdvertisementData
  BLEAdvertisementData oAdvertisementData = BLEAdvertisementData();
  oAdvertisementData.addData(adv_payload);
  pAdvertising->setAdvertisementData(oAdvertisementData);
  pAdvertising->setMinInterval(0x0640);
  pAdvertising->setMaxInterval(0x0C80);
  pAdvertising->setAdvertisementType(ADV_TYPE_NONCONN_IND);
  pAdvertising->setAdvertisementChannelMap(ADV_CHNL_ALL);
  pAdvertising->setDeviceAddress(rnd_addr, BLE_ADDR_TYPE_RANDOM);

  // start now
  esp_ble_gap_register_callback(esp_gap_cb);
  pAdvertising->start();
}

void loop() {
  delay(10000); // do nothing
}

[shiprec]

@ngxson Were you able to get it working with iOS17 devices?

[ngxson]

This is a re-implementation of the firmware found in https://github.com/seemoo-lab/openhaystack/tree/main/Firmware/ESP32

So, if the original firmware work with iOS 17, my version should also work