Minimal working example for serializing/deserializing abstract types without exposing :type field

[vincent-picaud]

Hi,

After some experimentation, I finally found a minimal working solution to serialize & deserialize structs containing abstract type instances.
I did not want to be intrusive by adding an extra :type field to the structures being serialized. I had a bit of trouble figuring out how to make it work, so I’m sharing my code here in case it helps someone else. Also, I’d appreciate if someone could double-check it for correctness or offer improvements.

Here's the working example:

  # Stuff to serialize/deserialize
  #
  abstract type AbstractShape end

  struct Circle <: AbstractShape
      radius::Float64                                # note: no extra :type field
  end

  struct Square <: AbstractShape
      side::Float64                                  # note: no extra :type field
  end

  struct ShapeHolder
      name::String
      shape::AbstractShape
  end

  # ================================================================

  using JSON3, StructTypes

  # ================================================================

  StructTypes.StructType(::Type{AbstractShape}) = StructTypes.AbstractType()
  StructTypes.subtypekey(::Type{AbstractShape}) = :type

  StructTypes.subtypes(::Type{AbstractShape}) = (circle=Circle,square=Square)

  # ================================================================

  StructTypes.StructType(t::Type{Circle}) = StructTypes.CustomStruct() # Mandatory otherwise lower() is not called
  StructTypes.lower(h::Circle) = Dict(
      "type" =>  "circle", 
      "radius" => h.radius
  )

  StructTypes.StructType(t::Type{Square}) = StructTypes.CustomStruct() # Mandatory otherwise lower() is not called
  StructTypes.lower(h::Square) = Dict(
      "type" =>  "square", 
      "side" => h.side
  )

  StructTypes.construct(::Type{Circle}, x::Dict) = Circle(x["radius"])
  StructTypes.construct(::Type{Square}, x::Dict) = Square(x["side"])

  # ================================================================

  function StructTypes.construct(t::Type{AbstractShape}, x::Dict)
      # field containing instance type information
      type_field = String(StructTypes.subtypekey(t))
      # get type information as string
      type_field_value = x[type_field]
      # get type
      type = StructTypes.subtypes(type_field_value)
      # create instance
      StructTypes.construct(type,x)
  end 

Now the example in action

  h = ShapeHolder("my shape", Circle(3.0))
  
  # serialize
  json_str = JSON3.write(h)         # is "{\"name\":\"my shape\",\"shape\":{\"radius\":3.0,\"type\":\"circle\"}}"

  # deserialize
 parsed = JSON3.read(json_str, ShapeHolder)     # is ShapeHolder("my shape", Circle(3.0))  

Thank you for your package !
Best,
Vincent

[Naunet]

A work-around is that using Union this just works with no added code.

The only problem is you need to define the Union. REPL defines subtypes which makes this super easy but it a dependency often avoided so you might need to write it out manually.

using JSON3

abstract type AbstractShape end

struct Circle <: AbstractShape
    radius::Float64
end

struct Square <: AbstractShape
    side::Float64
end

# ===========================================================

const AbstractShapeUnion = Union{subtypes(AbstractShape)...};

struct ShapeHolder
    name::String
    shape::AbstractShapeUnion
end

# ===========================================================

using Test

minify(str) = replace(str, r"[\n\t ]" => s"");

str = """[
    {    
        "name": "circle",
        "shape": {
            "radius": 2.5
        }
    },
    {    
        "name": "square",
        "shape": {
            "side": 2.5
        }
    }
]""";

arr = JSON3.read(str, Vector{ShapeHolder})
@test JSON3.write(arr) == minify(str)